Automate your API catalog with Terraform

This how-to requires you to install Terraform.

This is a Konnect tutorial and requires a Konnect personal access token.

1. Create a new personal access token by opening the Konnect PAT page and selecting Generate Token.

2. Export your token to an environment variable:

    export KONNECT_TOKEN='YOUR_KONNECT_PAT'

   Copied!

3. Create an auth.tf file that configures the kong/konnect Terraform provider. Change server_url if you are using a region other than us:

   echo '
   terraform {
     required_providers {
       konnect = {
         source  = "kong/konnect"
       }
       konnect-beta = {
         source  = "kong/konnect-beta"
       }
     }
   }
      
   provider "konnect" {
     server_url = "https://us.api.konghq.com"
   }
      
   provider "konnect-beta" {
     server_url            = "https://us.api.konghq.com"
   }
   ' > auth.tf

   Copied!

4. Next, initialize your project and download the provider:

   terraform init

   Copied!

The provider automatically uses the KONNECT_TOKEN environment variable if it is available. If you would like to use a custom authentication token, set the personal_access_token field alongside server_url in the provider block.

To use this tutorial, you need the following Kong Konnect roles:

• Portal Creator
• Content Editor
• Gateway Service Admin
• API Creator
• API Publisher

For this tutorial, you’ll need Kong Gateway entities, like Gateway Services and Routes, pre-configured. These entities are essential for Kong Gateway to function but installing them isn’t the focus of this guide.

1. Before configuring a Service and a Route, you need to create a Control Plane. If you have an existing Control Plane that you’d like to reuse, you can use the konnect_gateway_control_plane_list data source.

   echo '
   resource "konnect_gateway_control_plane" "my_cp" {
     name         = "Terraform Control Plane"
     description  = "Configured using the demo at developer.konghq.com"
     cluster_type = "CLUSTER_TYPE_CONTROL_PLANE"
   }
   ' > main.tf

   Copied!
2. Our example Service uses httpbin.org as the upstream, and matches the /anything path which echos the response back to the client.

   echo '
   resource "konnect_gateway_service" "httpbin" {
     name             = "example-service"
     protocol         = "https"
     host             = "httpbin.org"
     port             = 443
     path             = "/"
     control_plane_id = konnect_gateway_control_plane.my_cp.id
   }
   
   resource "konnect_gateway_route" "hello" {
     methods = ["GET"]
     name    = "Anything"
     paths   = ["/anything"]
   
     strip_path = false
   
     control_plane_id = konnect_gateway_control_plane.my_cp.id
     service = {
       id = konnect_gateway_service.httpbin.id
   }
   }
   ' >> main.tf

   Copied!

For this tutorial, you’ll need a Dev Portal pre-configured. These settings are essential for Dev Portal to function, but configuring them isn’t the focus of this guide. If you don’t have these settings already configured, follow these steps to pre-configure them:

1. Create a Dev Portal and add a page to display your published APIs:

   echo '
   resource "konnect_portal" "my_portal" {
     authentication_enabled               = false
     auto_approve_applications            = false
     auto_approve_developers              = true
     default_api_visibility               = "public"
     default_page_visibility              = "public"
     description                          = "...my_description..."
     display_name                         = "...my_display_name..."
     force_destroy                        = "false"
     name         = "My Portal"
     rbac_enabled = true
   }
   resource "konnect_portal_page" "my_portalpage" {
     portal_id   = konnect_portal.my_portal.id
     title       = "My Page"
     slug        = "/apis"
     description = "A custom page about developer portals"
     visibility  = "public"
     status      = "published"
   
     content = <<-MD
     # Welcome to My Dev Portal
   
     Explore the available APIs below:
   
     ::apis-list
     ---
     persist-page-number: true
     cta-text: "View APIs"
     ---
     MD
   }
   ' >> main.tf

   Copied!

2. Create all of the defined resources using Terraform:

   terraform apply -auto-approve

   Copied!